Final Output:

In Flash Authoring, first create two movieclips 'btn_mc' and 'movie_mc' in the Library and make sure you select 'Export to Actionscript' checkbox in Symbol Properties of these movieclips to make use of them in .as file.

Once these two movieclips are created, save this fla as 'test.fla' and create a new ActionScript File named 'test.as' in the same directory. We will be using this actionscript file as a Document Class for 'test.fla'. Inorder to use this .as file as a document class, we have to enter the name of the class(test) in ActionScript file in 'Class' textField under Publish Settings.

Once Document class is set, we are done with 'test.fla'. Move to 'test.as' to start with coding.

Initially we import required classes and start with class declaration:

package {

	import flash.display.MovieClip;
	import flash.display.Stage;
	import flash.events.MouseEvent;
	import fl.transitions.Tween;
	import fl.transitions.TweenEvent;
	import fl.transitions.easing.*;

	public class test extends MovieClip {
		public function test() {
                                   setup();
		}
	}
}

Note: Make sure the public class name is same as the name of .as file.

Declare some variabled we need as class member variables.

private var activeMovie:String="";
private var tempArray:Array=[];
private var names:Array=["home","profile","projects","contact","about"];
private var movie:MovieClip;
private var fwdTween:Tween;
private var bkTween:Tween;

Inside the constructor we have a function setup() called. We will look into this function now. First we need to arrange the buttons at the bottom on the stage by instantiating 'btn_mc' and giving 'x' and 'y' positions. Using 'name' property of the movieclip, give names to these buttons to know which button is being clicked.

var temp:MovieClip;

for (var i:int=0; i<5; i++) {
	temp = new btn_mc();
	temp.name=names[i];
	temp.x = i*(temp.width+10)+temp.width/2+10;
	temp.y=350;

	addChild(temp);
	tempArray.push(temp);
	temp.addEventListener(MouseEvent.CLICK, onClick);
}

We have declared an eventListener for MouseEvent.CLICK to handle click events.

By default we will show an instance of 'movie_mc' which shows the a label as Home with a Tween motion..

movie = new movie_mc();
movie.label_txt.text=names[0];
movie.x=-240;
movie.y=210;
addChild(movie);
fwdTween=new Tween(movie,"x",Elastic.easeInOut,-240,240,1,true);

Till now, we have arranged the buttons at the bottom and default movieclip that appears on launching the swf.

On clicking any of the button at the bottom, that specific movieclip should be displayed and the exisiting movie should go off the stage. This we will be doing inside the eventListener onClick().

On clicking a specific button, move the existing movie off the stage first, changing the label of moive_mc.label_txt to desired one and getting the new movieclip to the stage.

private function onClick(event:MouseEvent):void {

	if (event.target.name==activeMovie) {
		//Do nothing
	} else {
		bkTween=new Tween(movie,"x",Regular.easeOut,240,-240,0.5,true);
		bkTween.addEventListener(TweenEvent.MOTION_FINISH, newMotion);

		movie.label_txt.text=event.target.name;
		movie.x=-240;
		movie.y=210;
		addChild(movie);

		activeMovie=event.target.name;
	}
}

private function newMotion(e:TweenEvent):void{
	fwdTween=new Tween(movie,"x",Regular.easeOut,-240,240,0.5,true);
}

As this is a simple menu, we are just changing the label the movie_mc. Incase if the content of the movie_mc varies with different tabs, we can add that specific content into movie_mc based on the tab clicked.

Final test.as:

package {

	import flash.display.MovieClip;
	import flash.display.Stage;
	import flash.events.MouseEvent;
	import fl.transitions.Tween;
	import fl.transitions.TweenEvent;
	import fl.transitions.easing.*;

	public class test extends MovieClip {
		private var activeMovie:String="";
		private var tempArray:Array=[];
		private var names:Array=["home","profile","projects","contact","about"];
		private var movie:MovieClip;
		private var fwdTween:Tween;
		private var bkTween:Tween;

		public function test() {
			setup();
		}

		private function setup():void {
			var temp:MovieClip;

			for (var i:int=0; i<5; i++) {
				temp = new btn_mc();
				temp.name=names[i];
				temp.x = i*(temp.width+10)+temp.width/2+10;
				temp.y=350;

				addChild(temp);
				tempArray.push(temp);
				temp.addEventListener(MouseEvent.CLICK, onClick);
			}

			movie = new movie_mc();
			movie.label_txt.text=names[0];
			movie.x=-240;
			movie.y=210;
			addChild(movie);
			fwdTween=new Tween(movie,"x",Elastic.easeInOut,-240,240,1,true);
		}

		private function onClick(event:MouseEvent):void {

			if (event.target.name==activeMovie) {
				//Do Nothing
			} else {
				bkTween=new Tween(movie,"x",Regular.easeOut,240,-240,0.5,true);
				bkTween.addEventListener(TweenEvent.MOTION_FINISH, newMotion);

				movie.label_txt.text=event.target.name;
				movie.x=-240;
				movie.y=210;
				addChild(movie);

				activeMovie=event.target.name;
			}
		}

		private function newMotion(e:TweenEvent):void{
			fwdTween=new Tween(movie,"x",Regular.easeOut,-240,240,0.5,true);
		}
	}
}

This is all we need to do to start with a basic menu in Profiles in Flash. This is just a way to do it. There are many different ways to do it.

You can get the source files here.

Just Explore Flash AS3

Currently, Samsung provides the SDK to only register CPs. The current number of CPs is 200 and there are about 80 applications in application store. Those numbers will increase as time goes. It recently announced the SAMSUNG APPS CONTEST 2010, calling developers to use their SDK and create new applications for TV.

Any developer who wants to create applications can

• download the SDK from http://www.pavv.co.kr/contest/,
• make their own application
• test it using an desktop emulator.

Developers can make applications using  Web technologies (HTML and JavaScript) and ADOBE FLASH Technology.

Hope this starts a new era of TV Apps using Flash Lite for Digital Home.

This device has several new menus with a very rich UI:

• TiVo Central
• TiVo Search
• Tivo Browser (Tivo Content Browsing, not a html browser)
• My Shows etc

Apart from this, the Remote is pretty exciting with QWERTY Keyboard and very much like the way needed to navigate different Applications.

Way to go Flash Lite for Digital Home...

The CE4100 will be available at speeds of up to 1.2 GHz, and will feature hardware-based decoding capabilities that can handle two 1080p video streams simultaneously, along with high-definition audio and 3D graphics. The system supports hardware-based decoding for MEG4, and integrated NAND flash controller, support for DDR2 and DDR3 memory, support for SATA-300 and USB 2.0, and 512K of L2 cache. The chip will support Flash Player 10, along with standards like OpenFGL ES 2.0 for developing media-intensive 3D applications; Adobe expects Flash 10 to be available for Sodaville devices in mid-2010.

Its really great to use such a product and lets flourish it further...

Looking forward for the exciting new application on AIR...

Here are the Logos of all the Versions of Photoshop till CS4...

Hope to see more of Photoshop in Future...

"The unix time stamp is a way to track time as a running total of seconds. This count starts at the Unix Epoch on January 1st, 1970. Therefore, the unix time stamp is merely the number of seconds between a particular date and the Unix Epoch."

In order to count the number of seconds till a time, we have method Date.getTime() in Flash. This will effectively return the number of seconds from the Unix Epoch till the Date.

This is how i tried to find out the number of seconds till today's System Time:

var myDate = new Date();
trace(myDate);
var unixTime = Math.round(myDate.getTime()/1000);
trace("Unix Time: "+unixTime);

Output:

Fri Jan 22 13:01:55 GMT+0530 2010
Unix Time: 1264145516

To verify if we got the correct Unix TimeStamp of the normal time, check it on any online Unix Timestamp converters.

Problem arised when tried to convert the Unix Time we got into normal timestamp in Flash.

var myDate = new Date();
trace(myDate);
var unixTime = Math.round(myDate.getTime()/1000);
trace("Unix Time: "+unixTime);

var dateNew = new Date();
dateNew.setTime(unixTime);
trace(dateNew);

Output:

Fri Jan 22 16:22:42 GMT+0530 2010
Unix Time: 1264157563
Thu Jan 15 20:39:17 GMT+0530 1970

If you observe closely, while converting the Unix Timestamp to normal time, the year that's returned is 1970. If we use a online Unix Timestamp Converter to get back the normal time, it returns approximately correct time by inputting the above Unix Timestamp.

That was strange to get the difference while converting Unix Timestamp to Normal TimeStamp. Just observed this behavior, so thought of sharing it to find a solution or answer how to overcome it.

Very proud to be part of ADOBE...